Image:Cosine fixed point.svg

Summary

Summary

Fixed point iteration of the cosine function.

Derived from en::Image:Sine fixed point.svg. Created with en:Gnuplot:

set term svg
set out "cos.svg"

set multiplot
set size ratio 0.5
unset key
unset border
set xrange [-pi/2:pi/2]
set yrange [0:1]
set xtics axis
set ytics axis
set xzeroaxis
set yzeroaxis

f(x) = cos(x)
x_0 = -1

unset parametric
set samples 100
plot x with lines lt 3
plot f(x) with lines lt 3

set parametric
iter2_x(x, n) = n>0 ? iter1_x(f(x), n-1) : x
iter1_x(x, n) = n>0 ? iter2_x(  x , n-1) : x
 iter_x(x, n) = n>0 ? iter2_x(  x , n-1) : x
iter2_y(y, n) = n>0 ? iter1_y(  y , n-1) : y
iter1_y(y, n) = n>0 ? iter2_y(f(y), n-1) : y
 iter_y(y, n) = n>0 ? iter2_y(f(y), n-1) : 0
set samples 21
plot [0:20] iter_x(x_0,t),iter_y(x_0,t) with lines lt 1

unset multiplot

Originally from en.wikipedia; description page is/was here.

2007-04-30 (first version); 2007-04-30 (last version)

Original uploader was Tinctorius at en.wikipedia Later versions were uploaded by EdC at en.wikipedia.

Released under the GNU Free Documentation License.