Image:Climate graph test.svg

From Wikipedia, the free encyclopedia

• Image
• File history
• File links

[edit] Summary

A climate graph of Helsinki created by me in gnuplot to see how it looks with librsvg; I plan on uploading a bunch of these. Data from http://www.bbc.co.uk/weather/world/city_guides/results.shtml?tt=TT004740.

gnuplot script:

set tics scale 0
set ytics #tc rgbcolor "#FF0000"
set y2tics 0,50,150 #tc rgbcolor "#006600"
set grid ytics
set xrange [0.5:12.5]
set yrange [-20:30]
set y2range [-100:150]
set ylabel "Avg temperature (°C)" #tc rgbcolor "#FF0000" font "Arial,16"
set y2label "Avg precipitation (mm)" #tc rgbcolor "#006600"
set style fill solid #border -1
set boxwidth 0.6
set key off
set term svg size 640,500 font "Arial,18"
set output "jee.svg" 
set object 1 rectangle from graph 0,0 to graph 1,1 behind fc rgbcolor "#EEEEff" lw 0
set label "max" at character 38,17 tc rgbcolor "#FF0000"
set label "min" at character 38,16 tc rgbcolor "#0000FF"
plot 'palmas.txt' using 1:5 with boxes axes x1y2 lc rgbcolor "#bbbbff",\
     'palmas.txt' using 1:3:xtic(2) with lines lc 3 lw 2,\
     'palmas.txt' using 1:4 with lines lc 1 lw 2

where palmas.txt contains

1 J -9 -3 56
2 F -10 -4 42
3 M -7 0 36
4 A -1 6 44
5 M 4 14 41
6 J 9 19 51
7 J 13 22 68
8 A 12 20 72
9 S 8 15 71
10 O 3 8 73
11 N -1 3 68
12 D -5 -1 66

[edit] Licensing

I, the copyright holder of this work, hereby release it into the public domain. This applies worldwide. In case this is not legally possible, I grant any entity the right to use this work for any purpose, without any conditions, unless such conditions are required by law.

File history

Click on a date/time to view the file as it appeared at that time.

• Search for duplicate files
• Edit this file using an external application

  See the setup instructions for more information.

File links