Image:Buck continuous discontinuous.svg

graph Us=f(Is) of a buck converter. This figure has been made using gnuplot 4.0 with the following source (released as belonging to the public domain):

# This file is used to plot the domains of continuous and
# discontinuous operation of a buck converter

# graph configuration
set terminal svg enhanced fname "Times" fsize 18
set output "buck_continuous_discontinuous.svg"

set key off
set mxtics 
set mytics 
set grid xtics ytics
set ylabel "Normalized Voltage"
set xlabel "Normalized current"
set format y '%0.2f'
set format x "%0.2f" 
set samples 1500

# labels displayed on the graph
set label 1 'discontinuous' at 0.02,0.28
set label 2 'continuous' at 0.1,0.24
set label 3 'D=0.1' at 0.24,0.13 right
set label 4 'D=0.3' at 0.24,0.33 right
set label 5 'D=0.5' at 0.24,0.53 right
set label 6 'D=0.7' at 0.24,0.73 right
set label 7 'D=0.9' at 0.24,0.93 right

# normalized voltage=g(normalized current)
f(x,D) = 1/(2*x/D**2+1)
g(x,D) = f(x,D)<=D?D:f(x,D)
x1(t) = t

#parametric functions for plotting of domain limit
set parametric
my_x(t) = (1-t)/2*t
my_y(t) = t


# the plot is set as parametric, so each curve is defined by two values: x,y
plot [0:1][0:0.25][0:1] t,g(t,0.1) lw 2, \
        t,g(t,0.3) lw 2 , \
        t,g(t,0.5) lw 2 ,\
        t,g(t,0.7) lw 2 ,\
        t,g(t,0.9) lw 2 , \
        t,g(t,1) lw 1 ,\
        my_x(t),my_y(t) lw 2

Then it was post-processed with inkscape.

April 2007

Cyril Buttay and Alessio Damato

see below