Image:Buck-boost continuous discontinuous.png

[edit] Summary

Cyril BUTTAY

Evolution of the output voltage of a buck-boost converter with the output current.

This figure has been made using gnuplot 4.0 and the following source (public domain)

# This file is used to plot the domains of continuous and
# discontinuous operation of a buck-boost converter

# graph configuration
set terminal postscript eps enhanced "Times-Roman" 24 
set encoding iso_8859_15
unset title
set line style 1 lt 10 lw 3 pt 0 ps 0
set line style 2 lt 3 lw 3 pt 0 ps 0
set border 15 lt 10 lw 4
set mxtics 
set mytics 
set grid xtics ytics
set ylabel "Normalized Voltage"
set xlabel "Normalized current"
set format y '%0.1f'
set format x "%0.2f" 
set samples 1000

# labels displayed on the graph
set label 1 'discontinuous' at 0.075,-0.6  center
set label 2 'continuous' at 0.175,-2.5 center
set label 3 'D=0.0' at 0.24,0.2 right
set label 4 'D=0.2' at 0.24,-0.45 right
set label 5 'D=0.4' at 0.24,-0.9 right
set label 6 'D=0.6' at 0.24,-1.7 right
set label 7 'D=0.8' at 0.24,-4.2 right

# normalized voltage=g(normalized current)
fdisc(x,D) = -D**2/(2*x)
fcont(x,D) = -D/(1-D)
g(x,D) = fdisc(x,D)>=fcont(x,D)?fcont(x,D):fdisc(x,D)
x1(t) = t

#parametric functions for plotting of domain limit
set parametric
my_x(t) = (1-t)*t/2
my_y(t) = -t/(1-t)

set output "buck-boost_continuous_discontinuous.eps"

# the plot is set as parametric, so each curve is defined by two values: x,y
plot [0:1][0:0.25][-6:1] t,g(t,0) ls 1 title '', \
        t,g(t,0.2) ls 1 title '', \
        t,g(t,0.4) ls 1 title '', \
        t,g(t,0.6) ls 1 title '', \
        t,g(t,0.8) ls 1 title '', \
        my_x(t),my_y(t) ls 2 title ''

[edit] Licensing

I, the copyright holder of this work, hereby publish it under the following licenses: Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation license, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled "GNU Free Documentation license". Aragonés | العربية | Asturianu | Български | বাংলা | ইমার ঠার/বিষ্ণুপ্রিয়া মণিপুরী | Brezhoneg | Bosanski | Català | Cebuano | Česky | Dansk | Deutsch | Ελληνικά | English | Esperanto | Español | Eesti | Euskara | فارسی | Suomi | Français | Gaeilge | Galego | עברית | Hrvatski | Magyar | Bahasa Indonesia | Ido | Íslenska | Italiano | 日本語 | ქართული | ភាសាខ្មែរ | 한국어 | Kurdî / كوردی | Latina | Lëtzebuergesch | Lietuvių | Bahasa Melayu | Nnapulitano | Nederlands | ‪Norsk (nynorsk)‬ | ‪Norsk (bokmål)‬ | Occitan | Polski | Português | Română | Русский | Slovenčina | Slovenščina | Shqip | Српски / Srpski | Svenska | తెలుగు | ไทย | Türkçe | Українська | اردو | Tiếng Việt | Volapük | Yorùbá | ‪中文(中国大陆)‬ | ‪中文(台灣)‬ | +/- This file is licensed under the Creative Commons Attribution ShareAlike license versions 2.5, 2.0, and 1.0 العربية | Български | Català | Česky | Dansk | Deutsch | English | Español | Euskara | فارسی | Français | עברית | Italiano | 日本語 | 한국어 | Lietuvių | Nederlands | Polski | Português | Русский | Svenska | தமிழ் | Türkçe | 中文 | 中文 | +/- You may select the license of your choice.

• Buck-boost converter