Logo (programming language)

From Wikipedia, the free encyclopedia

You have new messages (last change).
Logo
Logo turtle graphic
Logo turtle graphic
Paradigm: functional, educational
Appeared in: 1967
Designed by: Wally Feurzeig & Seymour Papert
Developer: Wally Feurzeig & Seymour Papert
Typing discipline: dynamic
Major implementations: UCBLogo, many others
Influenced by: Lisp

The Logo programming language is a functional programming language. It is an easier to read adaptation and dialect of the Lisp programming language; some have called it Lisp without the parentheses. It was created for educational use, more so for constructivist teaching, by Danny Bobrow, Wally Feurzeig and Seymour Papert. Today, it is known mainly for its "turtle graphics", but it also has significant facilities for handling lists, files, and I/O. Logo can be used to teach most computer science concepts, as UC Berkeley Lecturer Brian Harvey does in his "Computer Science Logo Style" trilogy.

Contents

[edit] History

Logo was created in 1967 at BBN, a Cambridge, Massachusetts research firm, by Wally Feurzeig and Seymour Papert[1]. Its intellectual roots are in artificial intelligence, mathematical logic and developmental psychology. The first four years of Logo research, development and teaching work was done at BBN. The first implementation was written in LISP on a PDP-1. Its name was "ghost". The goal was basic problem solving; the turtle gave immediate (non-written) feedback so bugs could be spotted. Lots of other effects have been proposed as causes. Power was not a significant factor in the design. However, ease of use for non-typists who had to use a Teletype, was a big consideration, plus informative error comments.

The turtle was a rather late innovation. Logo is not too much different now from the basic concepts before the first turtle. The first turtle was a radio controlled (wireless) floor roamer named "Irving". Irving had touch sensors and could do forward, back, right, left (rotations), and ding (Irving had a bell). The earliest school users were at Muzzey Jr High, Lexington MA.

[edit] Implementations

The most broadly used and prevalent implementation of Logo was Apple Logo - widely distributed by Apple Computer and developed by Logo Computer Systems Inc. (LCSI). LCSI also implemented versions of Logo for other platforms including Atari, IBM and Microsoft.

There were over 170 implementations and dialects of Logo, in February 2007, each of which has its own strengths. Many are object-oriented. A popular cross-platform implementation is UCBLogo. MSWLogo (and its successor FMSLogo), its freeware Windows derivative, is commonly used in schools in the United Kingdom. Another version, used in schools in the US and a number of countries in Latin America, is MicroWorlds Logo. MicroWorlds developed from an earlier product released in 1986 called LogoWriter, a popular product that combined Logo and word processing. Comenius Logo is available in Dutch, German, Czech etc. SOLI Logo was a French version widely used in primary schools in the 1980s. In 1984, ExperLogo for the Macintosh added turtles in 3D and on the surface of spheres. It was also compiled instead of interpreted and hence was very fast. Lego/Logo was a system for controlling the turtle or Lego motors and sensors, and was often used in the classroom in the mid 90's. ARLOGO is an Arabic port of UCBLOGO, considered the first open-source programming language in Arabic.

A modern derivative of Logo is a variation that allows thousands of "turtles", each moving independently. There are two popular implementations: MIT StarLogo and NetLogo. These derivatives allow for the exploration of emergent phenomena and come with many experiments in social studies, biology, physics, and many other sciences. Although the focus is on the interactions of a large number of independent agents, these variations still capture the original flavor of Logo.

There is no single agreed-upon Logo language definition or standard, only a loose tradition. As a result, there are substantial differences between the many dialects of Logo that have evolved. The code examples shown below would work in many Logo dialects, but not all.

Nowadays, Logo is utilized as an easy to use program to control a robot. Logo was interfaced with LEGO bricks (although later Lego decided to use an other language in the commercial LEGO Mindstorms products). An interface also exists for Cricket robots.

[edit] Programming

The idea is that a turtle with a pen strapped to it can be instructed to do simple things like move forward 100 spaces or turn around. From these building blocks you can build more complex shapes like squares, triangles, circles--using these to draw houses or sailboats.

The turtle moves with commands that are relative to its own position, "LEFT 90" meant rotate left by 90 degrees. A student could understand (and predict and reason about) the turtle's motion by imagining what they would do if they were the turtle. Papert called this "body syntonic" reasoning.

The idea of turtle graphics is also useful for example in Lindenmayer system for generating fractals.

[edit] Turtle programming

Logo's best-known feature is the "turtle", which is an on-screen cursor which can be given movement and drawing instructions, and is used to programmatically produce line graphics. It is called so because it is traditionally and most often represented pictorially as a turtle icon (though it can be represented by any icon).

It also can represent a robot and the movement of a robot.

The following are examples of turtle code. While seemingly very simple, turtles can be given groups of instructions, essentially creating libraries of more complex commands. In practice short forms are used. For example, "LEFT 90" is written "LT 90". Key words are usually written in upper case for beginners, but more advanced texts use lower case.

[edit] Example 1: a square

FORWARD 100
LEFT 90
FORWARD 100
LEFT 90
FORWARD 100
LEFT 90
FORWARD 100
LEFT 90

This draws a square with sides 100 units long.

[edit] Example 2: a triangle

The commands may be written on one line, or more. In this example we'll use the short form for FORWARD and RIGHT, which are FD and RT respectively.

FD 100 RT 120 FD 100 RT 120
FD 100 RT 120

[edit] Example 3: dotted line

The turtle's pen could be lifted and lowered, thus drawing a rudimentary dotted line. Anything written after the ; (semicolon) is ignored, allowing the coder to insert comments.

Dotted Line

FD 20    ;(drawing a line and moving)
PENUP    ;(now we've lifted the pen so it won't draw anything even if we do move)
FD 20    ;(not drawing but moving)
PENDOWN  ;(now we've lowered the pen so it draws a line wherever the turtle moves)
FD 20    ;(drawing a line and moving)
PENUP
FD 20    ;(etc...)
PENDOWN
FD 20


[edit] Example 4: loops

You could also use loop (repeat) commands. This would draw the exact same box as in the first example:

REPEAT 4 [FD 100 LEFT 90]

Which executes the command "FD 100 LEFT 90" four times. An approximation of a circle can be constructed easily with 360 small rotations and a step forward: REPEAT 360 [FD 1 RIGHT 1].

[edit] Example 5: new words

You can teach the turtle new words, i.e. groups of instructions, or procedures. This can be done from the Logo prompt or an Editor, which is invoked by EDALL in many Logo dialects. Here we define the word CHAIR.

Basic Chair

EDALL
 
TO CHAIR
REPEAT 4 [FD 100 RT 90]  FD 200
END


Once one is finished with the editor, it must be exited. The new word is saved into the available vocabulary, but the definition will be lost once the Logo interpreter is stopped. In this case, any time CHAIR is entered, "REPEAT 4 [FD 100 LEFT 90] FD 200" will be executed. CHAIR can be used as a command; for example, REPEAT 4 [CHAIR] would compound the CHAIR operation four times.

[edit] Example 6: erasing (in the UCBLogo dialect)

The turtle can erase a line, using the command PENERASE (PE). The pen can be restored with the command PENPAINT (PPT).

EDALL ;(to enter the editor mode, then the actual procedure)


TO ERASECHAIR
PE
BK 200 REPEAT 4 [FD 100 RT 90]  
PPT
END


CS CHAIR WAIT 200 ERASECHAIR

This example introduces two new instructions, which are best taught by running them through a Logo interpreter and observing the result. This typifies the general spirit of Logo.

[edit] Example 7: parameters: giving the word changeable information

Logo can pass extra information to its words, and return information. We must tell the word to expect something and give it a name. Notice the use of the colon. We are passing 'by value' and the colon is pronounced as 'the value of'. When the procedure is run with a command like CHAIR 200, the size takes the value 200 so we go 'FD the value of 200'.

EDALL ;(to enter the editor mode, then the actual procedure)
 
TO CHAIR  :thesize
REPEAT 4 [FD :thesize  RT 90] FD :thesize FD :thesize
END

Try

 CS REPEAT 9 [CHAIR 50 RT 20 CHAIR 100 WAIT 50 RT 20]

Pattern

If you do need help, type HELP, or HELP "HOME (note the single quote mark.)


[edit] The language

Logo is generally known as an interpreted language, although recently there have been developed compiled Logo dialects - like Lhogho or Liogo. Logo is not case dependent, but retains the case used for formatting. It is written in lines. It is a compromise between a sequential programming language with block structures, and a functional programming language. There is no 'standard' LOGO, but UCBLogo is highly regarded. It is a teaching language but its list handling facilities make it remarkably useful for producing useful scripts.

[edit] Functions and procedures

Each line is made up of "function calls", or subroutines in programming terminology, of which there are two types:

  • commands (which do something—effects—but don't return a value) like print.
  • operations (which just return a value, its output) like sum, first or readlist.

A command is similar to a Pascal procedure, and an operation is similar to a Pascal function. (See also: command-query separation, where a "query" is an "operation" in Logo). A special subset of operations, called predicates, which just output the word true or false, are conventionally written with a final p. Examples include emptyp, wordp, and listp.

  • Expressions can be primitives, or can be defined by the user.
  • Expressions can take zero, one or more parameters.

Mathematics in Logo uses prefix notation, like: sum :x :y, product :x :y, difference :x :y, quotient :x :y. Infix is also available.

help "keyword ;(will bring up a full description of the expression).

Logo allows for recursion, the process where a procedure calls itself.

[edit] Example 8: A spiral drawn using recursion

to spiral :size
   if  :size > 30 [stop] ; a condition stop
   fd :size rt 15        ; many lines of action
   spiral :size *1.02    ; the tailend recursive call
end

spiral 10

Recursive Spiral

[edit] Data

There are three datatypes in UCBLogo,

  • the word,
  • the list,
  • the array.

A number is a special case of word.

There is no static typing. The interpreter detects the datatype by context.

There are two important symbols

  • The colon :- this means 'the contents of'

This is an extremely useful symbol that keeps reminding students that a variable is really some 'place' in memory.

  • The quote- this means '"the word is evaluated as itself"', or '"its value after evaluation is the same as it was before"'. This is important.

A number is a special case of self evaluation- it really could be written with a quote 2 is really "2

Variable assignment (eg. x := y + 3) is handled in Logo with the make command:

   make "x sum :y 3

or

   make "x sum :y "3

make takes 2 parameters, the second of which here is sum :y "3. sum takes two 'parameters' and is an 'operation', thus the calculation is possible. "3 evaluates to 3, and :y takes the contents of the thing called y, these are summed giving a number.

The effect of make is to place the result into the first parameter. From a programmatical perspective, the first argument to make is passed "by reference", while the second is passed "by value".

[edit] Scoping

Variables don't have to be declared before use. Their scope is then global. A variable may be declared local, then its scope is limited to that procedure and its subprocedures (a.k.a. dynamic scope). Calling a 'procedure' with 'inputs', creates 'local variables' which hold the contents of the parameters.

[edit] Lists

Logo inherits lists from Lisp, and they are its primary method of storing "vectors". Arrays are also provided.

  • Operators exist to convert words into lists, and lists into arrays and back again.
  • This data type has the advantage over arrays that it is infinitely expandable. Data are extracted using the operations first, butfirst, last, butlast, butmember, member and item. Data elements are added using sentence fput and lput.
  • A list can be considered to be a queue with the operators queue and dequeue, or a stack with the operations push and pop.
  • Recursion rather than iteration is the natural method to process lists.

[edit] Example 9: using list primitives to extract the first five members of a list

One way would be to use iteration.

 to firstfive :alist
  ifelse lessp count :alist 6 [ op :alist ][make "olist []]
  repeat 5 [ make "olist lput first :alist  :olist   make "alist bf :alist ] output :olist
 end

 show firstfive [1 2 3 4 5 6 7 8 9 ]
 [1 2 3 4 5]
 foreach firstfive [1 2 3 4 5 6 7 8 9 ] show 10 - ?
 [9 8 7 6 5]

Another, more elegant way would be

 to firstn :num :list
  if :num = 0 [output []]
  output fput (first :list) (firstn :num-1 butfirst :list)
 end
 
 to firstfive :list
  output firstn 5 :list
 end

This method uses recursion, and is an example of a 'functional' rather than an 'imperative' programming approach.

[edit] Control structure commands

Logo provides several common control structures.

  • ifelse test [ do_if_true list ] [do_if_false list]

There are iteration commands

  • while condition [instruction list]
  • until condition [instruction list ]
  • repeat number [instruction list]

Recursion is Logo's preferred processing paradigm.

[edit] Template iteration

Logo also provides list-based control structures. The basic idea is that you have two lists

OPERATION [ a list of commands ] [ many data items ]

each of the commands is applied in turn to each of the data items. There are several of these template commands with names like MAP, APPLY, FILTER, FOREACH, REDUCE and CASCADE. They repesent four flavours of template iteration, known as explicit-slot, named-procedure, named-slot (or Lambda) and procedure-text.

show map [? * ? ] [ 5 6 7 ]
[25 36 49 ]
show filter [ (count ?) > 4 ] [ the quick brown fox jumps over the lazy dog ]
[quick brown jumps]
show foreach [1 2 3 4 5] [ ? * 10 ]
[10 20 30 40 50]

RUN [ list of commands ] ;run a list of commands  (or programs) from in a program.

[edit] Property lists

A property list is a special list where the odd number items are property names, and the even are property values. There are three commands to process property list.

pprop :listname :name :value ;to add a new pair to the list
remprop :listname :name :value ;to remove a pair to the list
show gprop :listname :name  ;to get the matching value from the list

[edit] I/O Commands

Text may be written to the command window (output stream) using print, show and to the graphics window using label

The standard commands are readlist readword readchar with the normal input stream being the keyboard. In Unix tradition the input stream can be changed, so input can come from a disk file. Similarly, output can be redirected.

openread [filename]
setread[filename]
setreadpos nn
readchar
setread[]
close [filename].

There are equivalent commands to change the output stream, openwrite, openappend, setwrite, setwritepos nn.

dribble [filename]

Creates a transcript of everything that is typed in or outputted to the command window.

nodribble

This turns it off.

[edit] Graphics

Turtle graphics is a powerful method of introducing thinking but LOGO also has a few useful Cartesian commands

home         ;returns the turtle to (0,0)
setx xx      
sety yy      ; sends the turtle, still drawing to (xx,yy)
seth nn      ; sets the turtle on a heading or compass bearing of (nn)

[edit] Example 10: calculating and drawing a sundial for a given latitude

This is a typical garden dial. The graphic can be printed and transferred to wood or brass to make an accurate garden timepiece.

to dial
  
  cs show [Type in your latitude as a whole number]
  make "latitude readword  ;uses keyboard input
  for [i 0 6 1][
     make "ang arctan product sin :latitude tan product  :i 15  ;the calculation
     rt :ang fd 200 bk 200 lt :ang                      ;draw the morning line
     lt :ang fd 200 bk 200 rt :ang                      ;use symmetry to draw the afternoon line
     ]
     pu setx -300 sety -300 seth 90 pd                  ;send the turtle to the bottom
     fd 300 seth 270 rt 90 - :latitude fd 300           ;draw the [[style]] or [[gnomon]]
     pu home pd                                         ;tidy it up
 end

A sundial plate must be calculated for its latitude using the formula

x= arctan( sin(latitude)*tan(HourDiff * 15) )

The Gnomon Angle = latitude.
Sundial in Berkeley, California
This dial is set for 38N, the latitude of Berkeley, California- the home of UCBLogo. A small correction should be made for Longitude.

[edit] GIF animations

Simple GIF animations may also be produced on MSWlogo version 6.5 with the "gifsave" command. An example of the result of this - an animation of a sabot separating from its shell - is given here (1000x1000 pixels). Another example is given below:

A simple, low color GIF animation of an oscillating polar rose, produced on MSWlogo.
A simple, low color GIF animation of an oscillating polar rose, produced on MSWlogo.




















[edit] MSWLogo extensions

MSWLogo supports multiple turtles, and 3D Graphics. MSWLogo allows input from COM ports and LPT ports and also 'hardware' ports. MSWLogo also supports a windows interface thus I/O is available through this GUI- and keyboard and mouse events can trigger interrupts.

cs show [40]
 make "latitude readword  ;uses keyboard input
 for [i 0 6 1][
    make "ang arctan product sin :latitude tan product  :i 15  ;the calculation
    rt :ang fd 200 bk 200 lt :ang                      ;draw the morning line
    lt :ang fd 200 bk 200 rt :ang                      ;use symmetry to draw the afternoon line
    ]
    pu setx -300 sety -300 seth 90 pd                  ;send the turtle to the bottom
    fd 300 seth 270 rt 90 - :latitude fd 300           ;draw the style or gnomon
    pu home pd                                         ;tidy it up
end

[edit] Hello World

Hello world program

  TO HELLO
    PRINT [Hello, world!]
  END

[edit] See also

[edit] Bibliography

[edit] External links

Retrieved from "http://en.wikipedia.org../../../l/o/g/Logo_%28programming_language%29.html"