Image:IvsV mosfet.png

From Wikipedia, the free encyclopedia

Image
File history
File links

Size of this preview: 800 × 560 pixel
Image in higher resolution (1500 × 1050 pixel, file size: 42 KB, MIME type: image/png)

	This is a file from the Wikimedia Commons. The description on its description page there is shown below.
	Commons is attempting to create a freely licensed media file repository. You can help.

[edit] Summary

Cyril BUTTAY

Drain current as a function of the drain-to-source voltage and the gate-to-source bias over the threshold voltage.

This file has been generated using gnuplot 4.0 and the following code (released in the public domain):

# This file is used to plot the I(V) curve set of a MOSFET

# graph configuration
set terminal postscript eps enhanced "Times-Roman" 24 
set encoding iso_8859_15
unset title
set line style 1 lt 10 lw 3 pt 0 ps 0
set line style 2 lt 3 lw 3 pt 0 ps 0
set border 15 lt 10 lw 4
set mxtics 
set mytics 
set grid xtics ytics
set xlabel "Drain to source voltage [V]"
set ylabel "Drain current [arbitrary unit]"
set format y '%0.0f'
set format x "%0.0f" 

# labels displayed on the graph
set label 1 'linear region' at 2,40 center
set label 2 'saturation region' at 7.5,30 center
set label 3 'V{_{GS}}-V{_{th}}=7 V' at 9.8,47 right
set label 4 '6 V' at 9.8,37.5 right
set label 5 '5 V' at 9.8,26.5 right
set label 6 '4 V' at 9.8,17.4 right
set label 7 '3 V' at 9.8,10.5 right
set label 8 '2 V' at 9.8,5.5 right
set label 9 '1 V' at 9.8,2.5 right

# Drain current in linear region
linear(vds,vgsvth)=2*vgsvth*vds-vds**2
# Drain current in saturation region
saturation(vds,vgsvth)=vgsvth**2
# Drain current 
draincurrent(vds,vgsvth)=(vds>vgsvth?saturation(vds,vgsvth):linear(vds,vgsvth))
# limit between saturation and linear regions
limit(vds)=vds**2

set output "IvsV_mosfet.eps"

plot [0:10][0:50] draincurrent(x,1) ls 1 title '',\
        draincurrent(x,2) ls 1 title '',\
        draincurrent(x,3) ls 1 title '',\
        draincurrent(x,4) ls 1 title '',\
        draincurrent(x,5) ls 1 title '',\
        draincurrent(x,6) ls 1 title '',\
        draincurrent(x,7) ls 1 title '',\
        limit(x) ls 2 title ''

the eps file generated was converted in png format by the following command (linux)

convert -density 300 IvsV_mosfet.eps IvsV_mosfet.png

[edit] Licensing

I, the author of this work, hereby publish it under the following licenses:

Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled "GNU Free Documentation License".