Image:IvsV IGBT.png

[edit] Summary

[edit] Licensing

I, the author of this work, hereby publish it under the following licenses: Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled "GNU Free Documentation License". العربية | Česky | Deutsch | English | Español | Français | Italiano | 日本語 | 한국어 | Nederlands | Polski | Português | Slovenčina | Svenska | עברית +/- This file is licensed under the Creative Commons Attribution ShareAlike license versions 2.5, 2.0, and 1.0 You may select the license of your choice.

Made using gnuplot V4.0 and the following source:

# This file is used to plot the I(V) curve set of a MOSFET

# graph configuration
set terminal postscript eps enhanced "Times-Roman" 24 
set encoding iso_8859_15
unset title
set line style 1 lt 10 lw 3 pt 0 ps 0
set line style 2 lt 3 lw 3 pt 0 ps 0
set border 15 lt 10 lw 4
set mxtics 
set mytics 
set grid xtics ytics
set xlabel "Collector-Emitter voltage [V]"
set ylabel "Collector current [arbitrary unit]"
set format y '%0.0f'
set format x "%0.0f" 

# labels displayed on the graph
set label 3 'V{_{GE}}-V{_{th}}=7 V' at 9.8,47 right
set label 4 '6 V' at 9.8,37.5 right
set label 5 '5 V' at 9.8,26.5 right
set label 6 '4 V' at 9.8,17.4 right
set label 7 '3 V' at 9.8,10.5 right
set label 8 '2 V' at 9.8,5.5 right
set label 9 '1 V' at 9.8,2.5 right

# The model is basically that of a mosfet, with a diode in series
# Drain current in linear region
linear(vds,vgsvth)=2*vgsvth*vds-vds**2
# Drain current in saturation region
saturation(vds,vgsvth)=vgsvth**2
# Drain current 
draincurrent(vds,vgsvth)=(vds>vgsvth?saturation(vds,vgsvth):linear(vds,vgsvth))
# limit between saturation and linear regions
limit(vds)=vds**2
# diode forward voltage:
Vf(t,vgsvth)=2*0.026*log(draincurrent(t,vgsvth)/10e-8)

set output "IvsV_IGBT.eps"
set parametric
set sample 2000
# this is totally non physical: we calculate the current in the drain of the mosfet,
# then use this value to calculate the voltage drop in the diode, and then plot Vf+voltage
# on the x-axis, and the current on the y-axis. Then, I divide the voltage across the MOSFET
# by an arbitrary factor (4) to get a steeper curve.
plot [0:40 ][0:10][0:50] Vf(t,1)+t/4,draincurrent(t,1) ls 1 title '',\
        Vf(t,2)+t/4,draincurrent(t,2) ls 1 title '',\
        Vf(t,3)+t/4,draincurrent(t,3) ls 1 title '',\
        Vf(t,4)+t/4,draincurrent(t,4) ls 1 title '',\
        Vf(t,5)+t/4,draincurrent(t,5) ls 1 title '',\
        Vf(t,6)+t/4,draincurrent(t,6) ls 1 title '',\
        Vf(t,7)+t/4,draincurrent(t,7) ls 1 title ''