Image:Buck continuous discontinuous.png

From Wikipedia, the free encyclopedia

Image
File history
File links

Download high-resolution version (1500x1050, 38 KB)

This is a file from the Wikimedia Commons. The description on its description page there is shown below.

[edit] Summary

Cyril BUTTAY

graph Us=f(Is) of a buck converter. This figure has been made using gnuplot 4.0 with the following source (released as belonging to the public domain):

# This file is used to plot the domains of continuous and
# discontinuous operation of a buck converter

# graph configuration
set terminal postscript eps enhanced "Times-Roman" 24 
set encoding iso_8859_15
unset title
set line style 1 lt 10 lw 3 pt 0 ps 0
set line style 2 lt 3 lw 3 pt 0 ps 0
set border 15 lt 10 lw 4
set mxtics 
set mytics 
set grid xtics ytics
set ylabel "Normalized Voltage"
set xlabel "Normalized current"
set format y '%0.2f'
set format x "%0.2f" 
set samples 1000

# labels displayed on the graph
set label 1 'discontinuous' at 0.02,0.23 
set label 2 'continuous' at 0.1,0.23
set label 3 'D=0.1' at 0.24,0.13 right
set label 4 'D=0.3' at 0.24,0.33 right
set label 5 'D=0.5' at 0.24,0.53 right
set label 6 'D=0.7' at 0.24,0.73 right
set label 7 'D=0.9' at 0.24,0.93 right

# normalized voltage=g(normalized current)
f(x,D) = 1/(2*x/D**2+1)
g(x,D) = f(x,D)<=D?D:f(x,D)
x1(t) = t

#parametric functions for plotting of domain limit
set parametric
my_x(t) = (1-t)/2*t
my_y(t) = t

set output "buck_continuous_discontinuous.eps"

# the plot is set as parametric, so each curve is defined by two values: x,y
plot [0:1][0:0.25][0:1] t,g(t,0.1) ls 1 title '', \
        t,g(t,0.3) ls 1 title '', \
        t,g(t,0.5) ls 1 title '',\
        t,g(t,0.7) ls 1 title '',\
        t,g(t,0.9) ls 1 title '', \
        t,g(t,1) ls 1 title '',\
        my_x(t),my_y(t) ls 2 title ''

Then it is converted in png format using the following command (Linux):

convert -density 300 file.eps file.png

[edit] Licensing

I, the author of this work, hereby publish it under the following licenses:

Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled "GNU Free Documentation License".