AWK (programming language)

From Wikipedia, the free encyclopedia

You have new messages (last change).
AWK
Paradigm: scripting language, procedural, event-driven
Appeared in: 1977, last revised 1985, current POSIX edition is IEEE Std 1003.1-2004
Designed by: Alfred Aho, Peter Weinberger, and Brian Kernighan
Typing discipline: none; can handle strings, integers and floating point numbers; regular expressions
Major implementations: awk, GNU Awk, mawk, nawk, MKS AWK, Thompson AWK (compiler), Awka (compiler)
Dialects: old awk oawk 1977, new awk nawk 1985, GNU Awk
Influenced by: C, SNOBOL4, Bourne shell
Influenced: Perl, Korn Shell (ksh93, dtksh, tksh), JavaScript
OS: Cross-platform
Website: [1]

AWK is a general purpose programming language that is designed for processing text-based data, either in files or data streams. The name AWK is derived from the surnames of its authors — Alfred Aho, Peter Weinberger, and Brian Kernighan; however, it is commonly pronounced "awk" and not as a string of separate letters. awk, when written in all lowercase letters, refers to the Unix or Plan 9 program that runs other programs written in the AWK programming language.

AWK is an example of a programming language that extensively uses the string datatype, associative arrays (that is, arrays indexed by key strings), and regular expressions. The power, terseness, and limitations of AWK programs and sed scripts inspired Larry Wall to write Perl. Because of their dense notation, all these languages are often used for writing one-liner programs.

AWK is one of the early tools to appear in Version 7 Unix and gained popularity as a way to add computational features to a Unix pipeline. A version of the AWK language is a standard feature of nearly every modern Unix-like operating system available today. AWK is mentioned in the Single UNIX Specification as one of the mandatory utilities of a Unix operating system. Besides the Bourne shell, AWK is the only other scripting language available in a standard Unix environment. Implementations of AWK exist as installed software for almost all other operating systems.

Contents

[edit] Structure of AWK programs

An AWK program is a series of

pattern { action }

pairs, where pattern is typically an expression and action is a series of commands. Each line of input is tested against all the patterns in turn and the action executed if the expression is true. Either the pattern or the action may be omitted. The pattern defaults to matching every line of input. The default action is to print the line of input.

In addition to a simple AWK expression, the pattern can be BEGIN or END causing the action to be executed before or after all lines of input have been read, or pattern1, pattern2 which matches the range of lines of input starting with a line that matches pattern1 up to and including the line that matches pattern2 before again trying to match against pattern1 on future lines.

In addition to normal arithmetic and logical operators, AWK expressions include the tilde operator, ~, which matches a regular expressions against a string. As a handy default, /regexp/ without using the tilde operator matches against the current line of input.

[edit] AWK commands

AWK commands are the statement that is substituted for action in the examples above. AWK commands can include function calls, variable assignments, calculations, or any combination thereof. AWK contains built-in support for many functions; many more are provided by the various flavors of AWK. Also, some flavors support the inclusion of dynamically linked libraries, which can also provide more functions.

For brevity, the enclosing curly braces ( { } ) will be omitted from these examples.

[edit] The print command

The print command is used to output text. The output text is always terminated with a newline. The simplest form of this command is:

print

This displays the contents of the current line. In AWK, lines are broken down into fields, and these can be displayed separately:

print $1
Displays the first field of the current line
print $1, $3
Displays the first and third fields of the current line, separated by a predefined string called the output field separator (OFS) whose default value is a single space character

Although these fields ($X) may bear resemblance to variables (the $ symbol indicates variables in perl), they actually refer to the fields of the current line. A special case, $0, refers to the entire line. In fact, the commands "print" and "print $0" are identical in functionality.

The print command can also display the results of calculations and/or function calls:

print 3+2
print foobar(3)
print foobar(variable)
print sin(3-2)

Output may be sent to a file:

print "expression" > "file name"

[edit] Variables, et cetera

Variable names can use any of the characters [A-Za-z0-9_], with the exception of language keywords. The operators + - * / are addition, subtraction, multiplication, and division, respectively. For string concatenation, simply place two variables (or string constants) next to each other, optionally with a space in between. String constants are delimited by double quotes. Statements need not end with semicolons. Finally, comments can be added to programs by using # as the first character on a line.

[edit] User-defined functions

In a format similar to C, function definitions consist of the keyword function, the function name, argument names and the function body. Here is an example of a function.

function add_three (number, temp) {
  temp = number + 3
  return temp
}

This statement can be invoked as follows:

print add_three(36)     # Outputs 39

Functions can have variables that are in the local scope. The names of these are added to the end of the argument list, though values for these should be omitted when calling the function. It is convention to add some whitespace in the argument list before the local variables, in order to indicate where the parameters end and the local variables begin.

[edit] Sample applications

[edit] Hello World

Here is the ubiquitous "Hello world program" program written in AWK:

BEGIN { print "Hello, world!"}

[edit] Print lines longer than 80 characters

Print all lines longer than 80 characters. Note that the default action is to print the current line.

length > 80

[edit] Print a count of words

Count words in the input, and print lines, words, and characters (like wc)

{
    w += NF
    c += length + 1
}
END { print NR, w, c }

[edit] Sum last word

{ s += $NF }
END { print s + 0 }

As there is no pattern for the first line of the program, every line of input matches by default so the s += $NF action is executed. s is incremented by the numeric value of $NF which is the last word on the line as defined by AWK's field separator, by default white-space. NF is the number of fields in the current line, e.g. 4. Since $4 is the value of the fourth field, $NF is the value of the last field in the line regardless of how many fields this line has, or whether it has more or less fields than surrounding lines.

(If the line has no fields then NF is 0, $0 is the whole line, which in this case is empty apart from possible white-space, and so has the numeric value 0.)

At the end of the input the END pattern matches so s is printed. However, since there may have been no lines of input at all, and so s has never been assigned to, it will by default be an empty string. Adding zero to a variable is an AWK idiom for coercing it from a string to a numeric value. (Catenating an empty string is to coerce from a number to a string, e.g. s "". Note, there's no operator to catenate strings, they're just placed adjacently.) With the coercion the program prints 0 on an empty input, without it an empty line is printed.

[edit] Match a range of input lines

$ yes Wikipedia | cat -n | awk 'NR % 4 == 1, NR % 4 == 3' | head -7
     1  Wikipedia
     2  Wikipedia
     3  Wikipedia
     5  Wikipedia
     6  Wikipedia
     7  Wikipedia
     9  Wikipedia
$

The yes and cat commands generate a series of numbered lines as example input. NR is the number of records, typically lines of input, AWK has so far read, i.e. the current line number, starting at 1 for the first line of input. % is the modulo operator. NR % 4 == 1 is true for the first, fifth, ninth, etc., lines of input. Likewise, NR % 4 == 3 is true for the third, seventh, eleventh, etc., lines of input. The range pattern is false until the first part matches, on line 1, and then remains true up to and including when the second part matches, on line 3. It then stays false until the first part matches again on line 5.

The first part of a range pattern being constantly true, e.g. 1, can be used to start the range at the beginning of input. Similarly, if the second part is constantly false, e.g. 0, the range continues until the end of input.

/^--cut here--$/, 0

Prints lines of input from the first line matching the regular expression ^--cut here--$ to the end.

[edit] Calculate word frequencies

Word frequency, (uses associative arrays)

BEGIN { FS="[^a-zA-Z]+"}

{ for (i=1; i<=NF; i++)
     words[tolower($i)]++
}

END { for (i in words)
    print i, words[i]
}

[edit] Self-contained AWK scripts

As with many other programming languages, self-contained AWK script can be constructed using the so-called "shebang" syntax.

For example, a UNIX command called hello.awk that prints the string "Hello, world!" may be built by creating a file named hello.awk containing the following lines:

#!/usr/bin/awk -f
BEGIN { print "Hello, world!"; exit }

[edit] AWK versions and implementations

AWK was originally written in 1977, and distributed with Version 7 Unix.

In 1985 its authors started expanding the language, most significantly by adding user-defined functions. The language is described in the book The AWK Programming Language, published 1988, and its implementation was made available in releases of UNIX System V. To avoid confusion with the incompatible older version, this version was sometimes known as "new awk" or nawk. This implementation was released under a free software license in 1996, and is still maintained by Brian Kernighan. (see external links below)

BWK awk refers to this the version by Brian W. Kernighan. It has been dubbed the "One True AWK" because of the use of the term in association with the book[1] that originally described the language, and the fact that Kernighan was one of the original authors of awk. FreeBSD refers to this version as one-true-awk[2].

gawk (GNU awk) is another free software implementation. It was written before the original implementation became freely available, and is still widely used. Many Linux distributions come with a recent version of gawk and gawk is widely recognized as the de-facto standard implementation in the Linux world; gawk version 3.0 was included as awk in FreeBSD prior to version 5.0. Subsequent versions of FreeBSD use BWK awk in order to avoid[3] the GPL, a more restrictive (in the sense that GPL licensed code cannot be modified to become proprietary software) license than the BSD license. [4]

xgawk is a SourceForge project[5] based on gawk. It extends gawk with dynamically loadable libraries.

mawk is a very fast AWK implementation by Mike Brennan based on a byte code interpreter. This is the default AWK that comes with Debian and Ubuntu.

Downloads and further information about these versions are available from the sites listed below.

Thompson AWK or TAWK is an AWK compiler for DOS and Windows, previously sold by Thompson Automation Software (which has ceased its activities).

Jawk is a SourceForge project[6] to implement AWK in Java. Extensions to the language are added to provide access to Java features within AWK scripts (i.e., Java threads, sockets, Collections, etc).

BusyBox includes a sparsely documented Awk implementation that appears to be complete, written by Dmitry Zakharov. This implementation is the smallest Awk implementation out there, suitable for embedded systems.

[edit] Digression

  • The bird emblematic of AWK (a.o. on The AWK Programming Language book cover) is the Auk.

[edit] Books

[edit] See also

[edit] References

  1. ^ The AWK Programming Language, ISBN 0-201-07981-X.
  2. ^ FreeBSD's work log for importing BWK awk into FreeBSD's core, dated 2005-05-16, downloaded 2006-09-20
  3. ^ FreeBSD's view of GPL Advantages and Disadvantages
  4. ^ FreeBSD 5.0 release notes with notice of BWK awk in the base distribution
  5. ^ xgawk at SourceForge
  6. ^ Jawk at SourceForge

[edit] External links


view • talk • edit
Unix command line programs (more)
File and file system management: cat | cd | chmod | chown | chgrp | cp | du | df | file | fsck | ln | ls | lsof | mkdir | more | mount | mv | pwd | rm | rmdir | split | touch | tree
Process management: anacron | at | chroot | crontab | kill | killall | nice | pgrep | pidof | pkill | ps | sleep | screen | time | timex | top | wait
User Management/Environment: env | finger | id | locale | mesg | passwd | su | sudo | uname | uptime | w | wall | who | whoami | write
Text processing: awk | cut | diff | ex | head | iconv | join | less | more | nkf | paste | sed | sort | tail | tr | uniq | wc | xargs
Shell programming: echo | expr | printf | unset Printing: lp
Communications:
inetd | netstat | ping | rlogin | traceroute		 Searching:
find | grep | strings		 Miscellaneous:
banner | bc | cal | man | size | yes
Retrieved from "http://en.wikipedia.org../../../a/w/k/AWK_%28programming_language%29_339b.html"